home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / pc / LOGIC Apple II 5.25" Library - DOS Part 3 / DOS064.dsk / LOAN INTEREST RATE.bas < prev    next >
BASIC Source File  |  2012-02-16  |  2KB  |  46 lines
  1. 10  PRINT "ANNUAL INTEREST RATE ON A LOAN"
  2. 20  PRINT 
  3. 29  REM  - STATEMENTS 30 TO 100 REQUEST USER INPUT
  4. 30  PRINT "REGULAR PAYMENT";
  5. 40  INPUT R
  6. 50  PRINT "TERM IN YEARS, MONTHS";
  7. 60  INPUT Y0,M
  8. 64  REM  - CALCULATE YEARS FROM YEARS AND MONTHS
  9. 65 Y = (12 *Y0 +M)/12
  10. 70  PRINT "PRINCIPAL";
  11. 80  INPUT P
  12. 90  PRINT "NUMBER OF PAYMENTS PER YEAR";
  13. 100  INPUT N
  14. 109  REM  - GUESS AN INTEREST RATE (10%) TO INITIATE TESTING
  15. 110 I = 10
  16. 119  REM  - I2*LAST GUESS OR ESTIMATE ( START WITH 0 )
  17. 120 I2 = 0
  18. 129  REM  - COMPUTE REGULAR PAYMENT USING GUESSED INTEREST RATE
  19. 130 R1 = (I *P/N)/(1 -1/((I/N +1) ^(N *Y)))
  20. 139  REM  - ROUND OFF TO NEAREST CNET
  21. 140 R1 =  INT(R1 *100 +.5)/100
  22. 149  REM  - I3=NUMBER USED TO CLOSE IN ON INTEREST RATE
  23. 150 I3 =  ABS(I -I2)/2
  24. 159  REM  - SAVE THIS GUESS
  25. 160 I2 = I
  26. 168  REM  - COMPARE COMPUTED PAYMENT (R1) TO INPUT PAYMENT (R);
  27. 169  REM  - IF THEY'RE EQUAL, LAST RATE GUESSED=APPROXIMATE REG. PAYMENT
  28. 170  IF R1 = R  THEN 230
  29. 180  IF R1 >R  THEN 210
  30. 189  REM  - R1<R, RATE MUST BE HIGHTER THAN LAST GUESS
  31. 190 I = I +I3
  32. 199  REM  - RETEST WITH NEW GUESS
  33. 200  GOTO 130
  34. 209  REM  R1>R, RATE MUST BE LOWER THAN LAST GUESS
  35. 210 I = I -I3
  36. 219  REM  - RETEST WITH NEW GUESS
  37. 220  GOTO 130
  38. 229  REM  - COMPUTE INTEREST TO PROPER PROPORTIONS, ROUND OFF, PRINT
  39. 230 I = (( INT((I *1000) *100 +.5))/100)/1000
  40. 240  PRINT "ANNUAL INTEREST RATE = ";I *100;"%"
  41. 250  PRINT 
  42. 259  REM  - RESTART OR END PROGRAM
  43. 260  PRINT "MORE DATA? (1=YES, 0=NO)";
  44. 270  INPUT X
  45. 280  IF X = 1  THEN 20
  46. 290  PRINT "<CTRL-D>RUN HELLO"